Annex A (informative) Grammar summary [gram]

A.2 Lexical conventions [gram.lex]

hex-quad:
	hexadecimal-digit hexadecimal-digit hexadecimal-digit hexadecimal-digit

universal-character-name:
	\u hex-quad
	\U hex-quad hex-quad

preprocessing-token:
	header-name
	import-keyword
	module-keyword
	export-keyword
	identifier
	pp-number
	character-literal
	user-defined-character-literal
	string-literal
	user-defined-string-literal
	preprocessing-op-or-punc
	each non-white-space character that cannot be one of the above

token:
	identifier
	keyword
	literal
	operator-or-punctuator

header-name:
	< h-char-sequence >
	" q-char-sequence "

h-char-sequence:
	h-char
	h-char-sequence h-char

h-char:
	any member of the source character set except new-line and >

q-char-sequence:
	q-char
	q-char-sequence q-char

q-char:
	any member of the source character set except new-line and "

pp-number:
	digit
	. digit
	pp-number digit
	pp-number identifier-nondigit
	pp-number ' digit
	pp-number ' nondigit
	pp-number e sign
	pp-number E sign
	pp-number p sign
	pp-number P sign
	pp-number .

identifier:
	identifier-nondigit
	identifier identifier-nondigit
	identifier digit

identifier-nondigit:
	nondigit
	universal-character-name

nondigit: one of
	a b c d e f g h i j k l m
	n o p q r s t u v w x y z
	A B C D E F G H I J K L M
	N O P Q R S T U V W X Y Z _

digit: one of
	0 1 2 3 4 5 6 7 8 9

keyword:
	any identifier listed in Table tab:lex.key
	import-keyword
	module-keyword
	export-keyword

preprocessing-op-or-punc:
	preprocessing-operator
	operator-or-punctuator

preprocessing-operator: one of
	#        ##       %:       %:%:

operator-or-punctuator: one of
	{        }        [        ]        (        )
	<:       :>       <%       %>       ;        :        ...
	?        ::       .        .*       ->       ->*      ~
	!        +        -        *        /        %        ^        &        |
	=        +=       -=       *=       /=       %=       ^=       &=       |=
	==       !=       <        >        <=       >=       <=>      &&       ||
	<<       >>       <<=      >>=      ++       --       ,
	and      or       xor      not      bitand   bitor    compl
	and_eq   or_eq    xor_eq   not_eq

literal:
	integer-literal
	character-literal
	floating-point-literal
	string-literal
	boolean-literal
	pointer-literal
	user-defined-literal

integer-literal:
	binary-literal integer-suffix${}_{opt}$
	octal-literal integer-suffix${}_{opt}$
	decimal-literal integer-suffix${}_{opt}$
	hexadecimal-literal integer-suffix${}_{opt}$

binary-literal:
	0b binary-digit
	0B binary-digit
	binary-literal '${}_{opt}$ binary-digit

octal-literal:
	0
	octal-literal '${}_{opt}$ octal-digit

decimal-literal:
	nonzero-digit
	decimal-literal '${}_{opt}$ digit

hexadecimal-literal:
	hexadecimal-prefix hexadecimal-digit-sequence

binary-digit: one of
	0  1

octal-digit: one of
	0  1  2  3  4  5  6  7

nonzero-digit: one of
	1  2  3  4  5  6  7  8  9

hexadecimal-prefix: one of
	0x  0X

hexadecimal-digit-sequence:
	hexadecimal-digit
	hexadecimal-digit-sequence '${}_{opt}$ hexadecimal-digit

hexadecimal-digit: one of
	0  1  2  3  4  5  6  7  8  9
	a  b  c  d  e  f
	A  B  C  D  E  F

integer-suffix:
	unsigned-suffix long-suffix${}_{opt}$ 
	unsigned-suffix long-long-suffix${}_{opt}$ 
	long-suffix unsigned-suffix${}_{opt}$ 
	long-long-suffix unsigned-suffix${}_{opt}$

unsigned-suffix: one of
	u  U

long-suffix: one of
	l  L

long-long-suffix: one of
	ll  LL

character-literal:
	encoding-prefix${}_{opt}$ ' c-char-sequence '

encoding-prefix: one of
	u8  u  U  L

c-char-sequence:
	c-char
	c-char-sequence c-char

c-char:
	any member of the basic source character set except the single-quote ', backslash \, or new-line character
	escape-sequence
	universal-character-name

escape-sequence:
	simple-escape-sequence
	octal-escape-sequence
	hexadecimal-escape-sequence

simple-escape-sequence: one of
	\'  \"  \?  \\
	\a  \b  \f  \n  \r  \t  \v

octal-escape-sequence:
	\ octal-digit
	\ octal-digit octal-digit
	\ octal-digit octal-digit octal-digit

hexadecimal-escape-sequence:
	\x hexadecimal-digit
	hexadecimal-escape-sequence hexadecimal-digit

floating-point-literal:
	decimal-floating-point-literal
	hexadecimal-floating-point-literal

decimal-floating-point-literal:
	fractional-constant exponent-part${}_{opt}$ floating-point-suffix${}_{opt}$
	digit-sequence exponent-part floating-point-suffix${}_{opt}$

hexadecimal-floating-point-literal:
	hexadecimal-prefix hexadecimal-fractional-constant binary-exponent-part floating-point-suffix${}_{opt}$
	hexadecimal-prefix hexadecimal-digit-sequence binary-exponent-part floating-point-suffix${}_{opt}$

fractional-constant:
	digit-sequence${}_{opt}$ . digit-sequence
	digit-sequence .

hexadecimal-fractional-constant:
	hexadecimal-digit-sequence${}_{opt}$ . hexadecimal-digit-sequence
	hexadecimal-digit-sequence .

exponent-part:
	e sign${}_{opt}$ digit-sequence
	E sign${}_{opt}$ digit-sequence

binary-exponent-part:
	p sign${}_{opt}$ digit-sequence
	P sign${}_{opt}$ digit-sequence

sign: one of
	+  -

digit-sequence:
	digit
	digit-sequence '${}_{opt}$ digit

floating-point-suffix: one of
	f  l  F  L

string-literal:
	encoding-prefix${}_{opt}$ " s-char-sequence${}_{opt}$ "
	encoding-prefix${}_{opt}$ R raw-string

s-char-sequence:
	s-char
	s-char-sequence s-char

s-char:
	any member of the basic source character set except the double-quote ", backslash \, or new-line character
	escape-sequence
	universal-character-name

raw-string:
	" d-char-sequence${}_{opt}$ ( r-char-sequence${}_{opt}$ ) d-char-sequence${}_{opt}$ "

r-char-sequence:
	r-char
	r-char-sequence r-char

r-char:
	any member of the source character set, except a right parenthesis ) followed by
		the initial d-char-sequence (which may be empty) followed by a double quote ".

d-char-sequence:
	d-char
	d-char-sequence d-char

d-char:
	any member of the basic source character set except:
		space, the left parenthesis (, the right parenthesis ), the backslash \, and the control characters
		representing horizontal tab, vertical tab, form feed, and newline.

boolean-literal:
	false
	true

pointer-literal:
	nullptr

user-defined-literal:
	user-defined-integer-literal
	user-defined-floating-point-literal
	user-defined-string-literal
	user-defined-character-literal

user-defined-integer-literal:
	decimal-literal ud-suffix
	octal-literal ud-suffix
	hexadecimal-literal ud-suffix
	binary-literal ud-suffix

user-defined-floating-point-literal:
	fractional-constant exponent-part${}_{opt}$ ud-suffix
	digit-sequence exponent-part ud-suffix
	hexadecimal-prefix hexadecimal-fractional-constant binary-exponent-part ud-suffix
	hexadecimal-prefix hexadecimal-digit-sequence binary-exponent-part ud-suffix

user-defined-string-literal:
	string-literal ud-suffix

user-defined-character-literal:
	character-literal ud-suffix

ud-suffix:
	identifier