Annex A (informative) Grammar summary [gram]

A.8 Classes [gram.class]

class-name:
	identifier
	simple-template-id

class-specifier:
	class-head { member-specification $_{o p t}$  }

class-head:
	class-key attribute-specifier-seq $_{o p t}$  class-head-name class-virt-specifier $_{o p t}$  base-clause $_{o p t}$ 
	class-key attribute-specifier-seq $_{o p t}$  base-clause $_{o p t}$

class-head-name:
	nested-name-specifier $_{o p t}$  class-name

class-virt-specifier:
	final

class-key:
	class
	struct
	union

member-specification:
	member-declaration member-specification $_{o p t}$ 
	access-specifier : member-specification $_{o p t}$

member-declaration:
	attribute-specifier-seq $_{o p t}$  decl-specifier-seq $_{o p t}$  member-declarator-list $_{o p t}$  ;
	function-definition
	using-declaration
	using-enum-declaration
	static_assert-declaration
	template-declaration
	explicit-specialization
	deduction-guide
	alias-declaration
	opaque-enum-declaration
	empty-declaration

member-declarator-list:
	member-declarator
	member-declarator-list , member-declarator

member-declarator:
	declarator virt-specifier-seq $_{o p t}$  pure-specifier $_{o p t}$ 
	declarator requires-clause
	declarator brace-or-equal-initializer $_{o p t}$ 
	identifier $_{o p t}$  attribute-specifier-seq $_{o p t}$  : constant-expression brace-or-equal-initializer $_{o p t}$

virt-specifier-seq:
	virt-specifier
	virt-specifier-seq virt-specifier

virt-specifier:
	override
	final

pure-specifier:
	= 0

conversion-function-id:
	operator conversion-type-id

conversion-type-id:
	type-specifier-seq conversion-declarator $_{o p t}$

conversion-declarator:
	ptr-operator conversion-declarator $_{o p t}$

base-clause:
	: base-specifier-list

base-specifier-list:
	base-specifier ... $_{o p t}$ 
	base-specifier-list , base-specifier ... $_{o p t}$

base-specifier:
	attribute-specifier-seq $_{o p t}$  class-or-decltype
	attribute-specifier-seq $_{o p t}$  virtual access-specifier $_{o p t}$  class-or-decltype
	attribute-specifier-seq $_{o p t}$  access-specifier virtual $_{o p t}$  class-or-decltype

class-or-decltype:
	nested-name-specifier $_{o p t}$  type-name
	nested-name-specifier template simple-template-id
	decltype-specifier

access-specifier:
	private
	protected
	public

ctor-initializer:
	: mem-initializer-list

mem-initializer-list:
	mem-initializer ... $_{o p t}$ 
	mem-initializer-list , mem-initializer ... $_{o p t}$

mem-initializer:
	mem-initializer-id ( expression-list $_{o p t}$  )
	mem-initializer-id braced-init-list

mem-initializer-id:
	class-or-decltype
	identifier